ColdFusion 9.0 Resources

cfcol

Description

Defines table column header, width, alignment, and text. Used within a cftable tag.

Syntax

<cfcol  
    header = "column header text" 
    text = "column text" 
    align = "left|right|center" 
    width = "number that indicates width of column">

Note: You can specify this tag’s attributes in an attributeCollection attribute whose value is a structure. Specify the structure name in the attributeCollection attribute and use the tag’s attribute names as structure keys.

History

ColdFusion MX: Added the ability to construct dynamic cfcol statements.

Attribute	Req/Opt	Default	Description
`header`	Required		Column header text. To use this attribute, you must also use the `cftablecolHeaders` attribute.
`text`	Required		Double-quotation mark-delimited text; determines what to display. Rules: same as for `cfoutput` sections. You can embed hyperlinks, image references, and input controls.
`align`	Optional	`left`	Column alignment: `left` `right` `center`
`width`	Optional	20	Column width. If the length of data displayed exceeds this value, data is truncated to fit. To avoid this, use an HTML `table` tag. If the surrounding `cftable` tag includes the `htmltable` attribute, `width` specifies the percent of the table width and it does not truncate text; otherwise, `width` specifies the number of characters.

Usage

At least one cfcol tag is required within the cftable tag. You must put cfcol and cftable tags adjacent in a page. The only tag that you can nest within the cftable tag is the cfcol tag. You cannot nest cftable tags.

To display the cfcolheader text, specify the cfcolheader and the cftablecolHeader attribute. If you specify either attribute without the other, the header does not display. No error is thrown.

Example

<!--- This example shows the use of cfcol and cftable to align  
    information returned from a query. ---> 
<!--- Query selects information from cfdocexamples data source. ---> 
<cfquery name = "GetEmployees" dataSource = "cfdocexamples"> 
    SELECT Emp_ID, FirstName, LastName, EMail, Phone, Department 
    FROM Employees 
</cfquery> 
<html> 
<body> 
<h3>cfcol Example</h3> 
<!--- Uses the HTMLTable attribute to display cftable as an HTML  
    table, rather than PRE formatted information ---> 
<cftable  
    query = "GetEmployees"  
    startRow = "1" colSpacing = "3"  
    HTMLTable colheaders> 
<!--- Each cfcol tag sets the width of a column in the table,  
    the header information, and the text/CFML for the cell. ---> 
    <cfcol header = "<b>ID</b>" 
        align = "Left" 
        width = 2 
        text= "#Emp_ID#"> 
    <cfcol header = "<b>Name/Email</b>"     
        align = "Left" 
        width = 15 
        text= "<a href = 'mailto:#Email#'>#FirstName# #LastName#</A>"> 
    <cfcol header = "<b>Phone Number</b>" 
        align = "Center" 
        width = 15 
        text= "#Phone#"> 
</cftable>